Invert mysensors relay

---

Hello all,

I have a sketch you can see below on a arduino nano with an dht sensor and a one channel relay.
The sketch is working and i can see it in pimatic. But when the relay is off in pimatic the red and green LED that
is on the circuit board of the relay are on when i turn on the relay only the red LED is on.
This means that when i plug out the power of the arduino the relay is also closed and that is not what i want.
So i would like to know if there is a way to invert it in pimatic or maybe you guys have an other solution.

#define MY_RADIO_NRF24
#define MY_REPEATER_FEATURE
#define MY_NODE_ID 1

#include <SPI.h>
#include <MySensors.h>
#include <DHT.h>

// Set this to the pin you connected the DHT's data pin to
#define DHT_DATA_PIN 6

// Set this offset if the sensor has a permanent small offset to the real temperatures
#define SENSOR_TEMP_OFFSET 0

// Sleep time between sensor updates (in milliseconds)
// Must be >1000ms for DHT22 and >2000ms for DHT11
static const uint64_t UPDATE_INTERVAL = 60000;

// Force sending an update of the temperature after n sensor reads, so a controller showing the
// timestamp of the last update doesn't show something like 3 hours in the unlikely case, that
// the value didn't change since;
// i.e. the sensor would force sending an update every UPDATE_INTERVAL*FORCE_UPDATE_N_READS [ms]
static const uint8_t FORCE_UPDATE_N_READS = 10;

#define CHILD_ID_HUM 0
#define CHILD_ID_TEMP 1
#define CHILD_ID_RLAY 2

#define RELAY_PIN  3
#define RELAY_ON 1
#define RELAY_OFF 0

#define TEMP 0
#define HUMI 1

byte state = 0;
bool metric = true;

MyMessage msgHum(CHILD_ID_HUM, V_HUM);
MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);
MyMessage msgRlay(CHILD_ID_RLAY, V_STATUS);

typedef struct {
  float last;
  uint8_t nNoUpdates;
} sensorState_t;

sensorState_t dhtState[2];

DHT dht;

void presentation()
{
  // Send the sketch version information to the gateway
  sendSketchInfo("TempHumidRelay", "1.1");

  // Register all sensors to gw (they will be created as child devices)
  present(CHILD_ID_HUM, S_HUM);
  present(CHILD_ID_TEMP, S_TEMP);
  present(CHILD_ID_RLAY, S_BINARY);

  // Ask the gateway for the units of measure to use
  metric = getConfig().isMetric;
}

void setup()
{
  // Make sure relays are off when starting up
  pinMode(RELAY_PIN, OUTPUT);
  digitalWrite(RELAY_PIN, RELAY_OFF);

  // Initialize the Temperature & Humidity sensor, first reading will be sent from loop()
  if (UPDATE_INTERVAL >= dht.getMinimumSamplingPeriod()) {
    dht.setup(DHT_DATA_PIN); // set data pin of DHT sensor and model (e.g. DHT_22, DHT_11)
  } else {
    Serial.println("Warning: UPDATE_INTERVAL is smaller than supported by the sensor!");
    Serial.println("Increase UPDATE_INTERVAL and re-upload sketch...");
  }

  // Request the latest relay status from the gateway
  Serial.println("Requesting initial value from controller");
  request(CHILD_ID_RLAY, V_STATUS);
}

void loop()
{
  // Sleep until next valid interal to read temperature and humidity
  wait(UPDATE_INTERVAL);

  // Read current temperature & humidity from DHT22
  dht.readSensor(true);
  float temperature = dht.getTemperature();

  // Only send temperature if it has changed since the last measurement or if we didn't send an update for n times
  if (temperature != dhtState[TEMP].last || dhtState[TEMP].nNoUpdates >= FORCE_UPDATE_N_READS) {
    dhtState[TEMP].last = temperature;
    temperature = metric ? temperature : dht.toFahrenheit(temperature);
    temperature += SENSOR_TEMP_OFFSET;
    send(msgTemp.set(temperature, 1));
    #ifdef MY_DEBUG
      Serial.print("T: ");
      Serial.println(temperature);
    #endif
    dhtState[TEMP].nNoUpdates = 0;
  }
  else if (isnan(temperature)) {
    Serial.println("Failed reading temperature from DHT!");
  } else {
    // Increase no update counter if the temperature stayed the same
    dhtState[TEMP].nNoUpdates++;
  }

  // Retrieve the current humidity
  float humidity = dht.getHumidity();

  // Only send humidity if it changed since the last measurement or if we didn't send an update for n times
  if (humidity != dhtState[HUMI].last || dhtState[HUMI].nNoUpdates >= FORCE_UPDATE_N_READS) {
    dhtState[HUMI].last = humidity;
    send(msgHum.set(humidity, 1));

    #ifdef MY_DEBUG
      Serial.print("H: ");
      Serial.println(humidity);
    #endif
    dhtState[HUMI].nNoUpdates = 0;

  } else if (isnan(humidity)) {
    Serial.println("Failed reading humidity from DHT");
  } else {
    // Increase no update counter if the humidity stayed the same
    dhtState[HUMI].nNoUpdates++;
  }
}

void receive(const MyMessage &message) {
  Serial.println("Received message...");

  if (message.type == V_STATUS) {
    // Change relay state
    state = message.getByte();
    digitalWrite(RELAY_PIN, state);
    send(msgRlay.set(state));
  }
}

@derksuh You should use a relay which can be jumpered so that it can be triggered by a high or low signal. I can recommend the following 5V relay:

https://de.aliexpress.com/item/Free-Shipping-1-Channel-Supports-High-and-Low-Trigger-5V-Relay-Module-with-Optocoupler/32452037656.html?spm=2114.13010608.0.0.RGDbVM&detailNewVersion=&categoryId=400103

@MrSponti Ok i se, but that is not the solution right now i don’t see why we can’t get it working the way it is now.

If you want the relay to be open when the power is off, you should use different contacts. So instead of normally closed use normally open contacts.

If i power up the node now when i am not at home the red led is burning.
But when i’m at home and i power it up after a couple of seconds also the green light burns.
this is because it gets a signal from the gateway i guess.

@derksuh

try to Change the head section of your Code from

#define RELAY_ON 1
#define RELAY_OFF 0

to

#define RELAY_ON 0
#define RELAY_OFF 1

edit: if there are only Start-up Problems edit

// Make sure relays are off when starting up
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, RELAY_OFF);

to

// Make sure relays are off when starting up
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, RELAY_ON);

@derksuh
How about to change your script.

#define RELAY_ON 0
#define RELAY_OFF 1

Jup, change the HIGH and LOW in your script and your fine, also make sure that after you set the pin for ouput you change the relay state so it is in it’s OFF state.

Tried what was wroted above but that didn’t do the trick.
When starting up the node the relay is not activated, as soon as it connected to the gateway the relay is activated so it has to do something with the gateway.

curious… maybe @sweebee knows a solution??

In setup

request(CHILD_ID_RLAY, V_STATUS);

You are requesting the status from the relay from the gateway, that sets the relay to the status known by the controller.

If the gateway starts, do you see the debug output “Received message…”?

I did not get it working the way i would like. I now used a different sketch.
here i had the same problem but i just set the relay_OFF from 0 to 1, and the Relay_ON from 1 to 0
And with this sketch it worked fine.

#define MY_NODE_ID 1
// Enable debug prints
#define MY_DEBUG

// Enable and select radio type attached
#define MY_RADIO_NRF24
//#define MY_RADIO_RFM69

#include <SPI.h>
#include <MySensors.h>
#include <DHT.h>

#define CHILD_ID_HUM 1
#define CHILD_ID_TEMP 2
#define HUMIDITY_SENSOR_DIGITAL_PIN 6
unsigned long SLEEP_TIME = 30000; // Sleep time between reads (in milliseconds)
unsigned long lastRefreshTime = 0; // Use this to implement a non-blocking delay function

#define RELAY_1  3  // Arduino Digital I/O pin number for first relay (second on pin+1 etc)
#define NUMBER_OF_RELAYS 1 // Total number of attached relays
#define RELAY_ON 0  // GPIO value to write to turn on attached relay
#define RELAY_OFF 1 // GPIO value to write to turn off attached relay



DHT dht;
float lastTemp;
float lastHum;
boolean metric = true;
MyMessage msgHum(CHILD_ID_HUM, V_HUM);
MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);


void setup()
{
  dht.setup(HUMIDITY_SENSOR_DIGITAL_PIN);

  metric = getConfig().isMetric;

  for (int sensor=1, pin=RELAY_1; sensor<=NUMBER_OF_RELAYS;sensor++, pin++) {
    // Then set relay pins in output mode
    pinMode(pin, OUTPUT);
    // Set relay to last known state (using eeprom storage)
    digitalWrite(pin, loadState(sensor)?RELAY_ON:RELAY_OFF);
  }
}

void presentation()
{
  // Send the Sketch Version Information to the Gateway
  sendSketchInfo("Badkamer", "1.3");

  // Register all sensors to gw (they will be created as child devices)
  present(CHILD_ID_HUM, S_HUM);
  present(CHILD_ID_TEMP, S_TEMP);

  for (int sensor=1, pin=RELAY_1; sensor<=NUMBER_OF_RELAYS;sensor++, pin++) {
    // Register all sensors to gw (they will be created as child devices)
    present(sensor, S_LIGHT);
  }
}


void loop()
{
  boolean needRefresh = (millis() - lastRefreshTime) > SLEEP_TIME;
  if (needRefresh)
  {
      lastRefreshTime = millis();

      float temperature = dht.getTemperature();
      if (isnan(temperature)) {
          Serial.println("Failed reading temperature from DHT");
      } else if (temperature != lastTemp) {
        lastTemp = temperature;
        if (!metric) {
          temperature = dht.toFahrenheit(temperature);
        }
        send(msgTemp.set(temperature, 1));
        Serial.print("T: ");
        Serial.println(temperature);
      }

      float humidity = dht.getHumidity();
      if (isnan(humidity)) {
          Serial.println("Failed reading humidity from DHT");
      } else if (humidity != lastHum) {
          lastHum = humidity;
          send(msgHum.set(humidity, 1));
          Serial.print("H: ");
          Serial.println(humidity);
      }

  }

}

void receive(const MyMessage &message) {
  // We only expect one type of message from controller. But we better check anyway.
  if (message.type==V_LIGHT) {
     // Change relay state
     digitalWrite(message.sensor-1+RELAY_1, message.getBool()?RELAY_ON:RELAY_OFF);
     // Store state in eeprom
     saveState(message.sensor, message.getBool());
     // Write some debug info
     Serial.print("Incoming change for sensor:");
     Serial.print(message.sensor);
     Serial.print(", New status: ");
     Serial.println(message.getBool());
   }
}

This sketch is only reading last known state from eeprom, not requesting it from node. So it will not notice a change of state during a downtime, but that’s no problem I think…