Share your MySensors project

---

MySensors-devices was fast, compact “simply” to build with an Arduino, NRF24l01+, a few wires, a soldering iron and an actor or sensor.

There are a lot of basics on http://www.mysensors.org/build/ and how to use in pimatic @https://www.npmjs.com/package/pimatic-mysensors but feel free to share your ideas, optimized sketches, project pictures, batterypowered arduinos and so on… relating to pimatic and mySensors in ths thread.

please hold the thread compact and clear to inspire other “builders” and share your ideas only.

lets begin.

I have create a batterypowered door-contact sensor for my balcondoor to turn my heating device beside off for saving energy and extend my alarm-rule.

Parts-List

• Arduino Pro Mini (16 mhz) running on 5v

• Mobile Batterypack (for mobiledevices like this)

• 3.3V StepDown Converter for Powering NRF

• Magnetic Switch

after soldering all together i remove the powerled on the voltage regulator-pcb…

…and remove the powerled and voltage regulator on the arduino-board with a sharp knife to save energy.

I thank @sweebee for his universal Arduino-sketch. it could be used every time you’ll ned a 0/1-state (pir, contact, soil, switch, and so on…) in pimatic, the arduino goes to sleep while standby and transmit the battery-level if changes.

#define MY_RADIO_NRF24
#include <MySensors.h>
#include <SPI.h>
#include <readVcc.h>

// ********** CONFIG **********************************


    #define MY_NODE_ID 2         // ID of node
    #define CHILD_ID 1            // ID of sensor
    #define PIR_PIN 3             // Pin connected to the PIR
    
    #define MIN_V 4700            // empty voltage (0%)
    #define MAX_V 5100            // full voltage (100%)

    #define MY_DEBUG              // Debug

// ****************************************************

MyMessage msg(CHILD_ID, V_TRIPPED);
int oldBatteryPcnt = -1;
int forceSend = 0;

void setup()
{
  sendSketchInfo("Contact Sensor", "2.0");
  present(CHILD_ID, S_MOTION);
  pinMode(PIR_PIN, INPUT);
}


void loop()
{
  
  // Get PIR status and send to the gateway
  resend(msg.set(digitalRead(PIR_PIN)),6);
  
  // Send batterylevel
  sendBattery(); 

  // Sleep until something happens with the PIR
  sleep(PIR_PIN-2, CHANGE); 
}

// FUNCTIONS

void sendBattery() // Send battery percentage to GW
{
  forceSend++;
  int batteryPcnt = min(map(readVcc(), MIN_V, MAX_V, 0, 100), 100); // Get VCC and convert to percentage      
  if (batteryPcnt != oldBatteryPcnt || forceSend >= 20) { // If battery percentage has changed
    sendBatteryLevel(batteryPcnt); // Send battery percentage to gateway
    oldBatteryPcnt = batteryPcnt; 
    forceSend = 0;
  }
}

void resend(MyMessage &msg, int repeats) // Resend messages if not received by GW
{
  int repeat = 1;
  int repeatDelay = 0;

  while ((!send(msg)) and (repeat < repeats)) {
      repeatDelay += 100;
      repeat++;
      delay(repeatDelay);
    }    
}

edit: mySensors 2.0 compatible

readVcc you get in sweebee’s github

after uploading the sketch and moving the magnet to the reed-contact, the mysensors-debug shows me output like this…

…and with a device like that…

    {
      "id": "MySensors_Contact",
      "name": "MySensors Contact",
      "class": "MySensorsButton",
      "nodeid": 2,
      "sensorid": 1,
      "batterySensor": true
    },

this was the result

i know the 8mhz arduino pro micro (running on 1mhz) and 3,3V was better for building batterpowered nodes, but its a long way from shenzhen to austria… so i`m still waiting and i use the parts for my first mysensors-device lying around here in my tinkerbox…

measurements about power-consume and batteryruntime-experience of the device coming soon…

Hereby my PH meter including waterproof temperature sensor.

The idea was to use it for my aquarium to switch my solenoid valve and measure my water temp: The sketch below has been updated to use the mysensor plugin using the MySensorPH class. Or using V_VAR1 = sensortype 24 in a multisensor.

Parts-list

• Waterproof Digital Temperature Temp Sensor Probe DS18b20 S7NF
• NRF24L01+ Wireless Module 2.4G
• Arduino open source professional PH probe incl meter
• Arduino Nano 3.3-5.5v

The sketch for PH and temp meter

/*
  Original code created by DFRobot for their probes, 
  adapted by tony.dijksterhuis@gmail.com Mysensors for the project.
*/


#include <SPI.h>
#include <MySensor.h>
#include <DallasTemperature.h>
#include <OneWire.h>
#include "Vcc.h"        // https://github.com/Yveaux/Arduino_Vcc

static const float VccMin = 0.0;        // Minimum expected Vcc level, in Volts. (0.6V for 1 AA Alkaline)
static const float VccMax = 3.3;        // Maximum expected Vcc level, in Volts. (1.5V for 1 AA Alkaline)
static const float VccCorrection = 3.29 / 3.31;  // Measured Vcc by multimeter divided by reported Vcc
Vcc vcc(VccCorrection);

#define CHILD_ID_PH 0
#define ArrayLenth 10               // times of collection
#define PH_SENSOR_ANALOG_PIN A0         // pH meter Analog output to Arduino Analog Input 0
#define LED_DIGITAL_PIN 13
#define Offset 0.00           //deviation compensate

#define CHILD_ID_TEMP 1
#define COMPARE_TEMP 1 // Send temperature only if changed? 1 = Yes 0 = No
#define ONE_WIRE_BUS 3 // Pin where dallase sensor is connected 
#define MAX_ATTACHED_DS18B20 16

unsigned long SLEEP_TIME = 30000; // Sleep time between reads (in milliseconds)
OneWire oneWire(ONE_WIRE_BUS); // Setup a oneWire instance to communicate with any OneWire devices (not just Maxim/Dallas temperature ICs)
DallasTemperature sensors(&oneWire); // Pass the oneWire reference to Dallas Temperature.

unsigned long lastSend = 0;
static const unsigned long SEND_FREQUENCY = 30000;  // Minimum time between send (in milliseconds)

MySensor gw;

float lastPhHValue;
static const float deltaPhValue = 0.5;

float lastTemperature[MAX_ATTACHED_DS18B20];
int numSensors=0;
boolean receivedConfig = false;
boolean metric = true; 

MyMessage msgPH(CHILD_ID_PH, V_VAR1);
MyMessage msg(CHILD_ID_TEMP,V_TEMP);

void setup()
{
    // Startup up the OneWire library
    sensors.begin();
    // requestTemperatures() will not block current thread
    sensors.setWaitForConversion(false);
    
    //gw.begin(NULL, 100, false); //deze gebruiken, 100 is de node_id, die weer gebruiken in pimatic
    gw.begin();
    //Serial.print("0;0;3;0;2;");Serial.print(LIBRARY_VERSION);
    
    pinMode(LED_DIGITAL_PIN, OUTPUT);
    numSensors = sensors.getDeviceCount();
    
    // Send the Sketch Version Information to the Gateway
    gw.sendSketchInfo("pHmeter", "1.0");
    
    // Register all sensors to gw (they will be created as child devices)
    gw.present(CHILD_ID_PH, S_WATER_QUALITY);

    // Present all sensors to controller
    for (int i=0; i<numSensors && i<MAX_ATTACHED_DS18B20; i++) {   
    gw.present(i, S_TEMP);
    }
}

void loop()
{
    // By calling process() you route messages in the background
    gw.process();
    read_PH();
    read_TEMP();

    gw.sleep(SLEEP_TIME);
}

void read_PH(){
   unsigned long now = millis();
    bool sendTime = now - lastSend > SEND_FREQUENCY;
    if (sendTime)
    {
        lastSend = now;
        
        //    float v = vcc.Read_Volts();
        //    Serial.print("VCC = " );
        //    Serial.print(v);
        //    Serial.println(" Volts" );
        
        int batteryPcnt = (int)vcc.Read_Perc(VccMin, VccMax);
        //    Serial.print("VCC = " );
        //    Serial.print(batteryPcnt);
        //    Serial.println(" %" );
        
        gw.sendBatteryLevel(batteryPcnt);
    }
    
    // Read PH_SENSOR_ANALOG_PIN in phValue
    float voltage = analogReadAverage(PH_SENSOR_ANALOG_PIN, 10) * 5.0 / 1024;
    
    // convert the millivolt into pH value
    float PhValue = 3.5 * voltage+Offset;
    
    
    
    
    if (sendTime || abs(PhValue - lastPhHValue) > deltaPhValue)
    {
        Serial.print("    pH:");
        Serial.print(PhValue, 2);
        Serial.println(" ");
        
        gw.send(msgPH.set(PhValue, 2)); // envoi au reseau avec deux decimales
        
        digitalWrite(LED_DIGITAL_PIN, digitalRead(LED_DIGITAL_PIN) ^ 1);
        
        lastPhHValue = PhValue;
    }
}


void read_TEMP(){
  sensors.requestTemperatures();

  // query conversion time and sleep until conversion completed
  int16_t conversionTime = sensors.millisToWaitForConversion(sensors.getResolution());
  // sleep() call can be replaced by wait() call if node need to process incoming messages (or if node is repeater)
  gw.sleep(conversionTime);

  // Read temperatures and send them to controller 
  for (int i=0; i<numSensors && i<MAX_ATTACHED_DS18B20; i++) {
 
    // Fetch and round temperature to one decimal
    float temperature = static_cast<float>(static_cast<int>((gw.getConfig().isMetric?sensors.getTempCByIndex(i):sensors.getTempFByIndex(i)) * 10.)) / 10.;
 
    // Only send data if temperature has changed and no error
    #if COMPARE_TEMP == 1
    if (lastTemperature[i] != temperature && temperature != -127.00 && temperature != 85.00) {
    #else
    if (temperature != -127.00 && temperature != 85.00) {
    #endif
 
      // Send in the new temperature
      gw.send(msg.setSensor(i).set(temperature,1));
      // Save new temperatures for next compare
      lastTemperature[i]=temperature;
    }
  }   
}







double analogReadAverage(uint8_t pin, unsigned long ms)
{
    double average = 0;
    int buffer[ArrayLenth];
    
    for (int i = 0; i < ArrayLenth; i++)
    {
        buffer[i] = analogRead(PH_SENSOR_ANALOG_PIN);
        delay(ms);
    }
    
    if (ArrayLenth < 5)
    {
        // less than 5, calculated directly statistics
        for (int i = 0; i < ArrayLenth; i++)
        {
            average += buffer[i];
        }
        average = average / ArrayLenth;
    }
    else
    {
        // Sort the values from small to large
        for (int i = 0; i < ArrayLenth; i++)
        {
            for (int j = i + 1; j < 10; j++)
            {
                if (buffer[i] > buffer[j])
                {
                    int temp = buffer[i];
                    buffer[i] = buffer[j];
                    buffer[j] = temp;
                }
            }
        }
        
        // take the average value of center sample
        for (int i = 2; i < ArrayLenth - 2; i++)
        {
            average += buffer[i];
        }
        
        average = average / (ArrayLenth - 4);
    }
    
    return average;
}

{
      "id": "phmeter",
      "name": "pHmeter",
      "class": "MySensorsPH",
      "nodeid": 99,
      "sensorid": 1,
      "batterySensor": true     
    }

well i got a few:

10x of those motion sensors:

1x light sensor that measures the light level:

2x wall remotes to use “old” wall switches.

2x LED strip dimmer

1x kWh pulse meter

And the gateway

I had a problem where one one my fountains could not receive the 433Mhz messages from homeduino. So I created a MySensors KaKu (Klik aan Klik uit) transmitter.

It has a default address and you can use different dimmers/switches by using a different sensor id. In this case the sensor id == kaku unit.

This sketch works for KaKu, CoCo, Elro …

// ********** CONFIG **********************************

    #define MY_NODE_ID 16       // ID of node
    #define TX_PIN 8              // Pin connected to the 433MHz transmitter
    #define ADDRESS 38484         // KaKu ID

    #define MY_DEBUG              // Debug
    #define MY_REPEATER_FEATURE   // Repeater

// ****************************************************

#define MY_RADIO_NRF24
#include <NewRemoteTransmitter.h>
#include <SPI.h>
#include <MySensor.h>

NewRemoteTransmitter transmitter(ADDRESS, TX_PIN, 260, 3);

void setup() {
  sendSketchInfo("KaKu transmitter", "1.0");
}

void loop() {  
}

void receive(const MyMessage &message) {
  // If switch
  if (message.type==V_STATUS) {
    Serial.print("Switching to ");
    Serial.println(message.getBool());
    transmitter.sendUnit(message.sensor, message.getBool());
  }
  // If dimmer
  if (message.type==V_PERCENTAGE) {
    int dimlevel = round(0.15 * atoi(message.data));
    Serial.print("Dimming to ");
    Serial.println(dimlevel);
    transmitter.sendDim(message.sensor, dimlevel); 
  }
}

Hi, just wanted to show you a Multi sensor PIR based on the IKEA Molgan. I have used the mysensors procol for it. During my “investigation” I destroyed the original IKEA pir, but next one I am going to use the original Ikea PIR. The sensor runs on two AAA and has a PIR, LDR Light sensor and a dallas temp sensor. I want to add some pictures, how do I add them without uploading them to a seperate server?
I have uploaded them to the mysensors page: [http://forum.mysensors.org/topic/3756/multisensor-pir-based-on-ikea-molgan]

Love this one! Need to buy some of those molgans

very nice project!! and those molgan’s are relatively cheap with 5 Euro/piece.
gonna get my hands on them when i am at ikea next time.

Yesterday i build some more sensors

based on

• 3,3V Arduino Pro mini (@sweebee 's Pro-Mini-Mod’s), 1,20€/p

• NRF24l01 1.27mm Arduino Pro Mini Adapter, 0,75€/p

• Mini NRF24L01+ SMD 1.27MM, 1,50€/p

• Plastic Electronic Project Box 85/50/21mm , 1,40€/p

4,85€ for Baseparts, i think thats okay

My Soil Moisture Sensors:

• Soil Humidity Hygrometer Sensor Module Moisture, 0,60€/p

Sketch:

#include <MySensor.h>
#include <SPI.h>
#include <readVcc.h>

// ********** CONFIG **********************************

    #define MY_RADIO_NRF24
    #define NODE_ID 3         // ID of node
    #define CHILD_ID 3            // ID of sensor
    #define INPUT_PIN 3             // OUT-Pin of Moisture Sensor
    #define VCC_PIN 4              // VCC-Pin of Moisture Sensor
    
    #define MIN_V 2000            // empty voltage (0%)
    #define MAX_V 3200            // full voltage (100%)

// ****************************************************

MyMessage msg(CHILD_ID, V_LEVEL);
MySensor node;

int oldBatteryPcnt;
int sentValue;
int forceSend = 0;

void setup()
{
  node.begin(NULL, NODE_ID, false);
  node.sendSketchInfo("Moisture Sensor", "1.0");
  node.present(CHILD_ID, S_MOISTURE);
  pinMode(INPUT_PIN, INPUT);
  pinMode(VCC_PIN, OUTPUT);
}

void loop()
{
  digitalWrite(VCC_PIN, HIGH); // Turn on Moisture sensor
  // Get Percent
  int value = analogRead(INPUT_PIN);  // Get Moisture
  int percent = map(value, 0, 700, 0, 100);
    resend(msg.set(percent), 2); // Send PIR status to gateway
    sentValue = percent;
 

  // Send batterylevel
  sendBattery(); 

  digitalWrite(VCC_PIN, LOW); // Turn off Moisture sensor

  // Sleep 1 hour
  node.sleep(3600000);      // Sending every hour to Gateway
}

// FUNCTIONS

void sendBattery() // Send battery percentage to GW
{
  forceSend++;
  int batteryPcnt = min(map(readVcc(), MIN_V, MAX_V, 0, 100), 100); // Get VCC and convert to percentage      
  if (batteryPcnt != oldBatteryPcnt || forceSend >= 20) { // If battery percentage has changed
    node.sendBatteryLevel(batteryPcnt); // Send battery percentage to gateway
    oldBatteryPcnt = batteryPcnt; 
    forceSend = 0;
  }
}

void resend(MyMessage &msg, int repeats) // Resend messages if not received by GW
{
  int repeat = 0;
  int repeatDelay = 0;
  boolean ack = false;

  while ((ack == false) and (repeat < repeats)) {
    if (node.send(msg)) {
      ack = true;
    } else {
      ack = false;
      repeatDelay += 100;
    } 
    repeat++;
    delay(repeatDelay);
  }
}

Pimatic-device-config

    {
      "class": "MySensorsMulti",
      "id": "Soil_Gummibaum",
      "name": "Erdfeuchte Gummibaum",
      "attributes": [
        {
          "name": "Erdfeuchte Gummibaum",
          "nodeid": 3,
          "sensorid": 3,
          "type": "integer",
          "unit": "%",
          "sensortype": 37
        },
        {
          "name": "Battery",
          "nodeid": 3,
          "type": "battery",
          "unit": "%"
        }
      ]
    }

and how it looks like

My Door/Windos Contact Sensors

• Magnetic Reed-Switch, 0,91€/p

Sketch:

#include <MySensor.h>
#include <SPI.h>
#include <readVcc.h>

// ********** CONFIG **********************************

    #define MY_RADIO_NRF24
    #define NODE_ID 8          // ID of node
    #define CHILD_ID 8            // ID of sensor
    #define REED_PIN 3             // Pin connected to the Reed-contact, other to GND
    
    #define MIN_V 2000            // empty voltage (0%)
    #define MAX_V 3200            // full voltage (100%)

// ****************************************************

MyMessage msg(CHILD_ID, V_TRIPPED);
MySensor node;

int oldBatteryPcnt;
int sentValue;
int forceSend = 0;

void setup()
{
  node.begin(NULL, NODE_ID, false);
  node.sendSketchInfo("Contact Sensor", "1.2");
  node.present(CHILD_ID, S_MOTION);
  pinMode(REED_PIN, INPUT);
  digitalWrite(REED_PIN, HIGH);
}

void loop()
{
  
  // Get REED
  int value = digitalRead(REED_PIN); // Get value of State
  if (value != sentValue) { // If status of reedcontact has changed
    resend(msg.set(value), 5); // Send reedcontact status to gateway
    sentValue = value;
  }

  // Send batterylevel
  sendBattery(); 

  // Sleep until something happens with the sensor
  node.sleep(REED_PIN-2, CHANGE); 
}

// FUNCTIONS

void sendBattery() // Send battery percentage to GW
{
  forceSend++;
  int batteryPcnt = min(map(readVcc(), MIN_V, MAX_V, 0, 100), 100); // Get VCC and convert to percentage      
  if (batteryPcnt != oldBatteryPcnt || forceSend >= 20) { // If battery percentage has changed
    node.sendBatteryLevel(batteryPcnt); // Send battery percentage to gateway
    oldBatteryPcnt = batteryPcnt; 
    forceSend = 0;
  }
}

void resend(MyMessage &msg, int repeats) // Resend messages if not received by GW
{
  int repeat = 0;
  int repeatDelay = 0;
  boolean ack = false;

  while ((ack == false) and (repeat < repeats)) {
    if (node.send(msg)) {
      ack = true;
    } else {
      ack = false;
      repeatDelay += 100;
    } 
    repeat++;
    delay(repeatDelay);
  }
}

Pimatic-device-config

    {
      "id": "MySensors_Contact_Sleeproom",
      "name": "Fenster Kinderzimmer",
      "class": "MySensorsButton",
      "nodeid": 8,
      "sensorid": 8,
      "batterySensor": true
    }

and how it looks like

My Water-gauge Sensor

• Rain Water sensor water, 0,34€/p

Sketch

#include <MySensor.h>
#include <SPI.h>
#include <readVcc.h>

// ********** CONFIG **********************************

    #define MY_RADIO_NRF24
    #define NODE_ID 6         // ID of node
    #define CHILD_ID 6            // ID of sensor
    #define INPUT_PIN 1             // OUT-Pin of Sensor
    #define VCC_PIN 4              // VCC-Pin of Sensor
    
    #define MIN_V 2000            // empty voltage (0%)
    #define MAX_V 3200            // full voltage (100%)

// ****************************************************

MyMessage msg(CHILD_ID, V_LEVEL);
MySensor node;

int oldBatteryPcnt;
int sentValue;
int forceSend = 0;

void setup()
{
  node.begin(NULL, NODE_ID, false);
  node.sendSketchInfo("Water Sensor", "1.0");
  node.present(CHILD_ID, S_MOISTURE);
  pinMode(INPUT_PIN, INPUT);
  pinMode(VCC_PIN, OUTPUT);
}

void loop()
{
  digitalWrite(VCC_PIN, HIGH); // Turn on Moisture sensor
  // Get Percent
  int value = analogRead(INPUT_PIN);  // Get Moisture
  int percent = map(value, 0, 1023, 0, 100);
    resend(msg.set(percent), 2); // Send PIR status to gateway
    sentValue = percent;
 

  // Send batterylevel
  sendBattery(); 

  digitalWrite(VCC_PIN, LOW); // Turn on Moisture sensor

  // Sleep 4 hours
  node.sleep(14400000); 
}

// FUNCTIONS

void sendBattery() // Send battery percentage to GW
{
  forceSend++;
  int batteryPcnt = min(map(readVcc(), MIN_V, MAX_V, 0, 100), 100); // Get VCC and convert to percentage      
  if (batteryPcnt != oldBatteryPcnt || forceSend >= 20) { // If battery percentage has changed
    node.sendBatteryLevel(batteryPcnt); // Send battery percentage to gateway
    oldBatteryPcnt = batteryPcnt; 
    forceSend = 0;
  }
}

void resend(MyMessage &msg, int repeats) // Resend messages if not received by GW
{
  int repeat = 0;
  int repeatDelay = 0;
  boolean ack = false;

  while ((ack == false) and (repeat < repeats)) {
    if (node.send(msg)) {
      ack = true;
    } else {
      ack = false;
      repeatDelay += 100;
    } 
    repeat++;
    delay(repeatDelay);
  }
}

Pimatic device config

    {
      "class": "MySensorsMulti",
      "id": "Soil_Palme",
      "name": "Wasserstand Palme",
      "attributes": [
        {
          "name": "Wasserstand Palme",
          "nodeid": 6,
          "sensorid": 6,
          "type": "integer",
          "unit": "%",
          "sensortype": 37
        },
        {
          "name": "Battery",
          "nodeid": 6,
          "type": "battery",
          "unit": "%"
        }
      ]
    }

and how they looks like

@dynamite, nice PIR-Case!! looks very good i want 5 of them too… would you like to share your sketch ans schematics with us??

edit: added #define MY_RADIO_NRF24 for MySensors 2.0

@dynamite, could you please share a schema of your wonderfull Ikea PIR (hack)? That would be great!

@skipper79 @xCite86 Hi in the “prototype” I have destroyed the origininal PIR inside. So as soon as I have bought a new one I am planning to make a howto. Basically it is now based on a reversed pir (I have desoldered some components and put them at the front side to make the back flat), an arduino 3V and a dallas temp sensor and of course the NRF24l01.

@sweebee

2x wall remotes to use “old” wall switches.

How did you wire those? I have a double switch I like to be able to turn on/off with pimatic - since I don’t have a static current near the switch, I’ll need those One-wire actors: http://www.amazon.com/EQ3-76785-HomeMatic-Funk-Schalterschnittstelle-3-fach/dp/B00315VNOI?tag=meintechblog-140107-21

OR your solution! Can you please give me some details ?

@georg90 the cables that were connected for the lights are now connected to each other and removed from the switch. I connected a digital input from the arduino to the switch like you normally would. Make sure you use pin 2 or 3 with a interrupt. I also used a 470k pull-up to reduce power usage.

@sweebee said in Share your MySensors project:

@georg90 the cables that were connected for the lights are now connected to each other and removed from the switch. I connected a digital input from the arduino to the switch like you normally would. Make sure you use pin 2 or 3 with a interrupt. I also used a 470k pull-up to reduce power usage.

I don’t quite understand. You said “he cables that were connected for the lights are now connected to each other”. The lights are always on now?

Also, you connected a “normal” wall switch to the arduino? Does that work well? I tough that the switch would have too much resistance or something since it is made for 230V.
Also, are they click/push switches or two state switches?

@abmantis yes the light is always ‘on’ now because i have hue bulbs which require always 230v I implemented the arduino as pulse triggers, so no state because when you switch it off in pimatic, the state of the wall switch is wrong.

@sweebee I see.
So the switches are normal On/Off wall switches? And when their state changes, the arduino only notifies that there was a change, right? The state is stored/managed by pimatic?

You have no problem when the switch is on the on/connected state? It won’t drain the arduino’s battery?

Also (sorry for so many questions), have you ben able to fit them inside the wall switch “hole”?

I have to try that as soon as I receive my NRFs

@abmantis Yes just pulses to pimatic as a pir sensor and i have set it to absent by pimatic in 50ms.

I use a 470K pull-up, so the drain is very low. You could even try 1M ohm.

With 2 aaa batteries it fits easily.

I’m trying to get a pro mini + nrf smd wallswitch working right now, looks like it’s working!

I don’t want to be a complete noob, but that resistor is between the digital pin and ground? I don’t see it anywhere on your pictures

@lxz no, its a pull-UP. So its pulled to the vcc. input > vcc.

@sweebee In your post 3 you show your PIR sensors. They are running on 2 batteries and so is the PIR sensor. At least that is how it looks.
I have the exact same PIR sensor but mine doesn’t work on 3.3V (as the specs of course mention). I use your sketch but that one doesn’t work either.
Is that PIR really working on 3V or do you use a stepup regulator or is it a special PIR sensor or … or…?

@Harry-van-der-Wolf its a ‘hacked’ pir. http://techgurka.blogspot.nl/2013/05/cheap-pyroelectric-infrared-pir-motion.html?m=1